Zusätzliche Info in der Titelzeile anzeigen ...

[icke1954]

Hallo icfu, danke für die Erklärungen.

Du hast wohl nicht mit TC <7.50 getestet.

Nein, aber wie ich schon schrieb waren in den Variablen TMyPanel1-3 + 9 falsche oder keine verwertbaren Informationen, so wie in TPathPanel1,2 vorhanden. Hat sich jetzt nach dem Einsatz des Spy-Tools alles geklärt!

Vielleicht hilft dieser Thread, insbesondere das darin verlinkte Bild, beim Verständnis:

Und wie, jetzt hat es klick gemacht, sehen konnte ich es vorher nicht (TrayIcon=1)
icke

[icfu]

Hallo icfu, danke für die Erklärungen.

Gerne.

1 und 1 zusammenzaehlen sollte man aber schon koennen, wenn man mittlerweile "obsolete" Forderungen durchsetzen will. Von 2004 bis jetzt ist noch nicht einmal ein ganzes Jahrzehnt vergangen.

Fick Dich ins Knie, Du Wicht.

[mod]Hallo icfu,
Bitte andere Benutzer nicht beleidigen. Danke schön.

Hacker (Moderator)[/mod]

[norfie²]

1 und 1 zusammenzaehlen sollte man aber schon koennen, wenn man mittlerweile "obsolete" Forderungen durchsetzen will. Von 2004 bis jetzt ist noch nicht einmal ein ganzes Jahrzehnt vergangen.

Fick Dich ins Knie, Du Wicht.

IMHO wäre es charmanter gewesen, wenn Du stattdessen gleich ins Spamtrapforum gepostet hättest.

[icfu]

6042

[norfie²]

Deine "bescheidene" Meinung geht mir ... am Arsch vorbei.

Offensichtlich nicht.

War sonst noch was?

Ja, dass Du konsequent zu Deinen eigenen Aussagen stehst. Ausserdem wuerde ich es vorziehen, wenn Du auf Deine Faekalsprache verzichten wuerdest - aber offensichtlich fuehlst Du Dich dabei zu Hause und wohl.

[Hacker]

[mod]Bitte nichts persönliches mehr. Bleiben wir beim Thema.
Herzlichen dank.

Hacker (Moderator)[/mod]

[ghisler(Author)]

Es reicht, nach all den Jahren solltet Ihr 2 mittlerweile auch erwachsen sein, oder etwa nicht? Dann benehmt euch bitte entsprechend.

[tom*de]

»Wenn jeder alles von dem andern wüsste, es würde jeder gern und leicht verzeihen, es gäbe keinen Stolz mehr, keinen Hochmut«. (Hafis)
--

Ich nutze die coole AHK-Lösung von icfu, die x32 und x64 unterscheidet und im Titel anzeigt:

...Angepaßte Skriptversion für x32/x64, unterschiedliche Separatoren konfigurierbar:

Code: Select all

;*** Konfiguration Start
v_Separator32 := "  < | x32 | >  "
v_Separator64 := "  < | x64 | >  "
v_Timer := 250
;*** Konfiguration Ende

#Persistent
SetTimer, Timer, %v_Timer%

Timer:
hWnd := WinActive("ahk_class TTOTAL_CMD")
If (hWnd)
{
  WinGet, v_TCExe, ProcessName, ahk_id %hWnd%
  If (v_TCExe = "totalcmd.exe")
  {
    v_ActivePathControl := "TMyPanel3"
    v_LeftPathControl := "TPathPanel1"
    v_RightPathControl := "TPathPanel2"
    v_Separator := v_Separator32
  }
  Else
  {
    v_ActivePathControl := "Window5"
    v_LeftPathControl := "Window9"
    v_RightPathControl := "Window14"
    v_Separator := v_Separator64
  }
  ControlGetText, v_ActivePath, %v_ActivePathControl%
  v_ActivePath := RegExReplace(v_ActivePath, "(.+)>", "$1")
  ControlGetText v_LeftPath, %v_LeftPathControl%
  v_LeftPath := RegExReplace(v_LeftPath, "(.+\\).*", "$1")
  ControlGetText v_RightPath, %v_RightPathControl%
  v_RightPath := RegExReplace(v_RightPath, "(.+\\).*", "$1")
  If (v_ActivePath = v_ActivePathOld && v_LeftPath = v_LeftPathOld && v_RightPath = v_RightPathOld)
    Return
  v_InactivePath := (v_ActivePath = v_LeftPath) ? v_RightPath : v_LeftPath
  v_WinTitle := v_ActivePath . v_Separator . v_InactivePath
  WinSetTitle, %v_WinTitle%
  v_ActivePathOld := v_ActivePath
  v_LeftPathOld := v_LeftPath
  v_RightPathOld := v_RightPath
}
Return

Da ich mitunter 3 TC-Versionen aktiv habe: v7 in \apps\tc7\ und v8 (x32 und x64) in gemeinsamen Verzeichnis: \apps\tc\

würde ich gerne alle 3 Versionen in der angepassten Titelzeile erkennen...:

v_Separator32v7 := " < | v7x32 | > "
v_Separator32v8 := " < | v8x32 | > "
v_Separator64v8 := " < | v8x64 | > "

Wie kann ich TC-Version 7 und 8 mit AHK unterscheiden bzw. auslesen?

[icfu]

Wie kann ich TC-Version 7 und 8 mit AHK unterscheiden bzw. auslesen?

Der String $TCVersion$ wird durch vVersionsnummer ersetzt oder gelöscht, je nachdem, ob die Variable v_InsertTCVersion auf true oder false steht.

Code: Select all

;*** Konfiguration Start
v_Separator32 := "  < | $TCVersion$x32 | >  "
v_Separator64 := "  < | $TCVersion$x64 | >  "
v_InsertTCVersion := true
v_Timer := 250
;*** Konfiguration Ende

#Persistent
SetTimer, Timer, %v_Timer%

Timer:
hWnd := WinActive("ahk_class TTOTAL_CMD")
If (hWnd)
{
  WinGet, v_TCExe, ProcessName, ahk_id %hWnd%
  If (v_TCExe = "totalcmd.exe")
  {
    v_ActivePathControl := "TMyPanel3"
    v_LeftPathControl := "TPathPanel1"
    v_RightPathControl := "TPathPanel2"
    v_Separator := v_Separator32
  }
  Else
  {
    v_ActivePathControl := "Window5"
    v_LeftPathControl := "Window9"
    v_RightPathControl := "Window14"
    v_Separator := v_Separator64
  }
  If (v_InsertTCVersion)
  {
    WinGet, v_TCExePath, ProcessPath, ahk_id %hWnd%
    FileGetVersion, v_TCVersion, %v_TCExePath%
    v_TCVersion := "v" . SubStr(v_TCVersion, 1, 1)
  }
  StringReplace, v_Separator, v_Separator, $TCVersion$, %v_TCVersion%
  ControlGetText, v_ActivePath, %v_ActivePathControl%
  v_ActivePath := RegExReplace(v_ActivePath, "(.+)>", "$1")
  ControlGetText v_LeftPath, %v_LeftPathControl%
  v_LeftPath := RegExReplace(v_LeftPath, "(.+\\).*", "$1")
  ControlGetText v_RightPath, %v_RightPathControl%
  v_RightPath := RegExReplace(v_RightPath, "(.+\\).*", "$1")
  If (v_ActivePath = v_ActivePathOld && v_LeftPath = v_LeftPathOld && v_RightPath = v_RightPathOld)
    Return
  v_InactivePath := (v_ActivePath = v_LeftPath) ? v_RightPath : v_LeftPath
  v_WinTitle := v_ActivePath . v_Separator . v_InactivePath
  WinSetTitle, %v_WinTitle%
  v_ActivePathOld := v_ActivePath
  v_LeftPathOld := v_LeftPath
  v_RightPathOld := v_RightPath
}
Return

[tom*de]

Nach dem Update des AHK-Basic auf die aktuelle AutoHotkey_L wird nun auch der WinGet-Befehl: ProcessPath [v1.1.01+] und FileGetVersion [v1.1.04+] ausgeführt.

Damit funktioniert Dein Script prima, danke, icfu

[tom*de]

Damit es ab TC-Version TC 8.51b3 weiter funktioniert muss die Zeile:

Code: Select all

  If (v_TCExe = "totalcmd.exe")

geändert werden in:

Code: Select all

  If (v_TCExe = "TOTALCMD.EXE")

[tom*de]

Kleine Anpassungen für TC9: Wer in der TC-Titelzeile seine Pfade sehen mag (mit Hilfe von AHK):

Code: Select all

;*** Konfiguration Start
v_Separator32 := "  <---$TCVersion$x32--->  "
v_Separator64 := "  <---$TCVersion$x64--->  "
v_InsertTCVersion := true
v_Timer := 500
 ;*** Konfiguration Ende

 #Persistent
 SetTimer, Timer, %v_Timer%

 Timer:
 hWnd := WinActive("ahk_class TTOTAL_CMD")
 If (hWnd)
 {
   WinGet, v_TCExe, ProcessName, ahk_id %hWnd%
   If (v_TCExe = "totalcmd64.exe")
   {
     v_ActivePathControl := "Window11"
     v_LeftPathControl := "Window9"
     v_RightPathControl := "Window14"
     v_Separator := v_Separator64
   }
   Else
   {
     v_ActivePathControl := "TMyPanel3"
     v_LeftPathControl := "TPathPanel1"
     v_RightPathControl := "TPathPanel2"
     v_Separator := v_Separator32
   }
   If (v_InsertTCVersion)
   {
     WinGet, v_TCExePath, ProcessPath, ahk_id %hWnd%
     FileGetVersion, v_TCVersion, %v_TCExePath%
     v_TCVersion := "v" . SubStr(v_TCVersion,1,7)
   }
   StringReplace, v_Separator, v_Separator, $TCVersion$, %v_TCVersion%
   ControlGetText, v_ActivePath, %v_ActivePathControl%
   ControlGetText v_LeftPath, %v_LeftPathControl%
   ControlGetText v_RightPath, %v_RightPathControl%

   If (v_LeftPath = v_LeftPathOld && v_RightPath = v_RightPathOld)
     Return

   v_WinTitle := v_LeftPath . v_Separator . v_RightPath
   WinSetTitle, %v_WinTitle%
   v_ActivePathOld := v_ActivePath
   v_LeftPathOld := v_LeftPath
   v_RightPathOld := v_RightPath
 }
 Return