Hi,
I would like to create my personal TC setup to install my own plugins and my ini files directlywhen I want to install it on a new computer.
What are the registry keys I have to set to specify that I want the ini files in the TC folder and not in the windows folder?
Create my personal TC setup
Moderators: white, Hacker, petermad, Stefan2
- fabiochelly
- Power Member
- Posts: 603
- Joined: 2003-02-05, 12:03 UTC
- Location: Rambouillet, France
Create my personal TC setup
Fabio Chelly.
#60241
Lorsqu'on s'occupe d'informatique il faut faire comme les canards...
Paraître calme en surface et pédaler comme un forcené par en dessous
#60241
Lorsqu'on s'occupe d'informatique il faut faire comme les canards...
Paraître calme en surface et pédaler comme un forcené par en dessous
- André Martin
- Senior Member
- Posts: 245
- Joined: 2003-02-05, 15:46 UTC
- Location: Dresden, Germany
Just have a look on Aezay's post:
http://www.ghisler.ch/board/viewtopic.php?t=258
http://www.ghisler.ch/board/viewtopic.php?t=258
Browse the web with the HTTP SmartBrowserPlugin
Check your mails with the POP3/SMTP EmailPlugin!
Check your mails with the POP3/SMTP EmailPlugin!
If you plan on using InnoSetup (free installer creator) you could base you script on my script.
I put a password in because my ftp account are located inside the installer..
Code: Select all
[Setup]
AppName=total commander
AppVerName=total commander 5.51
DefaultDirName={pf}\total commander
DefaultGroupName=total commander
DisableProgramGroupPage=yes
DisableStartupPrompt=yes
DisableReadyMemo=yes
Password=123456
Uninstallable=no
Compression=zip/9
[Tasks]
Name: "startmenuicon"; Description: "create a &start menu icon"; GroupDescription: "Icons:"; Flags: unChecked
Name: "desktopicon"; Description: "create a &desktop icon"; GroupDescription: "Icons:"; Flags: unChecked
Name: "quicklaunchicon"; Description: "create a &quick launch icon"; GroupDescription: "Icons:"; MinVersion: 4,4; Flags: unChecked
[Files]
Source: "files\*.*"; DestDir: "{app}"; CopyMode: alwaysoverwrite; Flags: recursesubdirs
[Ini]
Filename: "{app}\wincmd.ini"; Section: "Configuration"; Key: "InstallDir"; String: "{app}"
Filename: "{app}\wincmd.ini"; Section: "PackerPlugins"; Key: "img"; String: "0,{app}\plugins\img.wcx"
Filename: "{app}\wincmd.ini"; Section: "PackerPlugins"; Key: "deb"; String: "4,{app}\plugins\deb.wcx"
Filename: "{app}\wincmd.ini"; Section: "PackerPlugins"; Key: "iso"; String: "0,{app}\plugins\iso.wcx"
Filename: "{app}\wincmd.ini"; Section: "PackerPlugins"; Key: "rpm"; String: "20,{app}\plugins\rpm.wcx"
Filename: "{app}\wincmd.ini"; Section: "PackerPlugins"; Key: "cpio"; String: "20,{app}\plugins\cpio.wcx"
Filename: "{app}\wincmd.ini"; Section: "PackerPlugins"; Key: "bz2"; String: "bz2=251,{app}\plugins\bzip2dll.wcx"
Filename: "{app}\wincmd.ini"; Section: "Lister"; Key: "IViewPath"; String: "{app}\tools\i_view32.exe"
Filename: "{app}\wincmd.ini"; Section: "user"; Key: "cmd1"; String: "{app}\tools\bin2iso.exe"
Filename: "{app}\wincmd.ini"; Section: "user"; Key: "cmd2"; String: "{app}\tools\filemon.exe"
Filename: "{app}\wincmd.ini"; Section: "user"; Key: "cmd3"; String: "{app}\tools\frhed.exe"
Filename: "{app}\wincmd.ini"; Section: "user"; Key: "cmd4"; String: "{app}\tools\i_view32.exe"
Filename: "{app}\wincmd.ini"; Section: "user"; Key: "cmd5"; String: "{app}\tools\kalender.exe"
Filename: "{app}\wincmd.ini"; Section: "user"; Key: "cmd6"; String: "{app}\tools\md5.bat"
Filename: "{app}\wincmd.ini"; Section: "user"; Key: "param6"; String: """""{app}\tools"" ""%n"" """
Filename: "{app}\wincmd.ini"; Section: "user"; Key: "cmd7"; String: "{app}\tools\procexp.exe"
Filename: "{app}\wincmd.ini"; Section: "user"; Key: "cmd8"; String: "{app}\tools\putty.exe"
Filename: "{app}\wincmd.ini"; Section: "user"; Key: "cmd9"; String: "{app}\tools\pwdspy.exe"
Filename: "{app}\wincmd.ini"; Section: "user"; Key: "cmd10"; String: "{app}\tools\regmon.exe"
Filename: "{app}\wincmd.ini"; Section: "user"; Key: "cmd11"; String: "{app}\tools\tcpview.exe"
Filename: "{app}\wincmd.ini"; Section: "user"; Key: "cmd12"; String: "{app}\tools\tdimon.exe"
Filename: "{app}\wincmd.ini"; Section: "user"; Key: "cmd13"; String: "{app}\tools\trout.exe"
Filename: "{app}\wincmd.ini"; Section: "user"; Key: "cmd14"; String: "{app}\tools\upx.exe"
Filename: "{app}\wincmd.ini"; Section: "FileSystemPlugins"; Key: "$linux drives"; String: "{app}\plugins\ex2fs.wfx"
Filename: "{app}\wincmd.ini"; Section: "Configuration"; Key: "editor"; String: "gvim.exe"
[Registry]
Root: HKCU; Subkey: "Software\Ghisler\Total Commander"; ValueType: string; ValueName: "FtpIniName"; ValueData: "{app}\wcx_ftp.ini"
Root: HKCU; Subkey: "Software\Ghisler\Total Commander"; ValueType: string; ValueName: "IniFileName"; ValueData: "{app}\wincmd.ini"
Root: HKCU; Subkey: "Software\Ghisler\Total Commander"; ValueType: string; ValueName: "InstallDir"; ValueData: "{app}"
[Icons]
Name: "{commonprograms}\total commander"; Filename: "{app}\totalcmd.exe"; Tasks: startmenuicon
Name: "{userdesktop}\total commander"; Filename: "{app}\totalcmd.exe"; Tasks: desktopicon
Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\total commander"; Filename: "{app}\totalcmd.exe"; MinVersion: 4,4; Tasks: quicklaunchicon
Name: "{sendto}\hex edit"; Filename: "{app}\tools\frhed.exe"; MinVersion: 4,4
[Run]
Filename: "{app}\totalcmd.exe"; Description: "launch total commander"; Flags: nowait postinstall skipifsilent
- fabiochelly
- Power Member
- Posts: 603
- Joined: 2003-02-05, 12:03 UTC
- Location: Rambouillet, France