[Autohotkey] Set Path In TC

[valuex]

The below AHK V2 script can help you to set the path in TC by sending message.

Code: Select all

;https://www.ghisler.ch/board/viewtopic.php?p=277574#256573
/*
The complete syntax is in fact : 
<Left>`r<Right>\0                       ; eg:  D:\xxx\   `r  E:\xxx\  \0
<Source>`r<Target>\0S                   ; eg:  D:\xxx\   `r  E:\xxx\  \0
<Left>`r<Right>\0T open in new Tab      ; eg:  D:\xxx\   `r  E:\xxx\  \0T
*/
TC_SetLeftPath(inpath) 
{
    ; inpath should be ended with \
    newPath:=inpath . "`r"
    TC_SetPath(newPath) 
}
TC_SetRightPath(inpath)
{
    ; inpath should be ended with \
    newPath:="`r" . inpath . "\0"
    TC_SetPath(newPath) 
}
TC_SetPath(userCommand) 
{
    ; https://www.autohotkey.com/boards/viewtopic.php?p=538463&sid=4471e03917209854441ac07ebdc70901#p538463
    static dwData := 17475  ;;Ord("C") +256*Ord("D")
    static WM_COPYDATA := 0x4A
    cbData := Buffer(StrPut(userCommand, 'CP0'))
    StrPut(userCommand, cbData, 'CP0')
    COPYDATASTRUCT := Buffer(A_PtrSize * 3)
    NumPut('Ptr', dwData, 'Ptr', cbData.size, 'Ptr', cbData.ptr, COPYDATASTRUCT)
    MsgResult:=SendMessage( WM_COPYDATA,, COPYDATASTRUCT,, 'ahk_class TTOTAL_CMD')
    return MsgResult
}

[Horst.Epp]

Sending data is fine, but I never need this in scripting
as there is always the way to control the left / right path of the active TC
using a command line with the /O switch.

[Fla$her]

2Horst.Epp
There is a big difference in speed, given the temporary creation of a new instance. I always give preference to TCFS2.exe /ef tcd(), except in cases with /P for a folder.