Zusätzliche Info in der Titelzeile anzeigen ...

tom*de · Post by *tom*de » 2009-03-10, 15:25 UTC

icfu wrote:Rechtsbündig wäre umständlicher Frickelkram, aber hier ist ein Skript, das den aktiven und inaktiven Pfad mit einem Separator trennt, den Du frei konfigurieren kannst.

Code: Select all

v_Separator := "  <--->  "

#Persistent
SetTimer, Timer, 250

Timer:
If WinActive("ahk_class TTOTAL_CMD")
{
  ControlGetText, v_ActivePath, TMyPanel2
  v_ActivePath := RegExReplace(v_ActivePath, "(.+)>", "$1")
  ControlGetText v_LeftPath, TMyPanel5
  v_LeftPath := RegExReplace(v_LeftPath, "(.+\\).*", "$1")
  ControlGetText v_RightPath, TMyPanel9
  v_RightPath := RegExReplace(v_RightPath, "(.+\\).*", "$1")
  If (v_ActivePath = v_ActivePathOld && v_LeftPath = v_LeftPathOld && v_RightPath = v_RightPathOld)
    Return
  v_InactivePath := (v_ActivePath = v_LeftPath) ? v_RightPath : v_LeftPath
; v_WinTitle := v_LeftPath . v_Separator . v_RightPath 
  v_WinTitle := v_ActivePath . v_Separator . v_InactivePath
  WinSetTitle, %v_WinTitle%
  v_ActivePathOld := v_ActivePath
  v_LeftPathOld := v_LeftPath
  v_RightPathOld := v_RightPath
}
Return

Icfu

Vista erlaubt sich, ohne die Schweiz zu fragen im Admin Modus (in einigen Fällen) den ADMINUSER^ - vor die schöne TC-Titelzeile zu hängen.

Weiß jemand was im og. Script zu ändern ist, dass wieder die Pfade und vielleicht ein Hinweis ADMIN in der Titelzeile zu sehen sind?

tom*de · Post by *tom*de » 2009-09-10, 14:38 UTC

Im o.g. Script muss man ab TC v7.50: TMyPanel2 mit => TMyPanel3 ersetzen.

Wie bekomm ich den inaktiven Pfad in 7.50? / Was muss ich für TMyPanel5 und TMyPanel9 im o.g. AHK-Script eintragen?
Hab vorerst TMyPanel5 mit TMyPanel6 ersetzt und eine ganz aussagekräftige Titelzeile fürs aktive Fenster.

icfu · Post by *icfu » 2009-09-10, 23:43 UTC

TMyPanel5 => TPathPanel1
TMyPanel9 => TPathPanel2

Icfu

tom*de · Post by *tom*de » 2009-09-11, 15:11 UTC

super. Danke.

tom*de · Post by *tom*de » 2011-12-04, 09:30 UTC

Habe aktuell den AHK-Code von Icfu im Einsatz der mir in Titelzeile des Fenstertitels die aktuellen TC-Verzeichnisse anzeigt. Bei mehreren Instanzen habe ich so schnell den richtigen TC gefunden...:

Code: Select all

v_Separator := "  <--->  "

#Persistent
SetTimer, Timer, 2000

Timer:
If WinActive("ahk_class TTOTAL_CMD")
{
  ControlGetText, v_ActivePath, TMyPanel3
  v_ActivePath := RegExReplace(v_ActivePath, "(.+)>", "$1\")
  ControlGetText v_LeftPath, TPathPanel1
  v_LeftPath := RegExReplace(v_LeftPath, "(.+\\).*", "$1")
  ControlGetText v_RightPath, TPathPanel2
  v_RightPath := RegExReplace(v_RightPath, "(.+\\).*", "$1")
  If (v_ActivePath = v_ActivePathOld && v_LeftPath = v_LeftPathOld && v_RightPath = v_RightPathOld)
    Return
  v_InactivePath := (v_ActivePath = v_LeftPath) ? v_RightPath : v_LeftPath
; v_WinTitle := v_LeftPath . v_Separator . v_RightPath 
  v_WinTitle := v_ActivePath . v_Separator . v_InactivePath
  WinSetTitle, %v_WinTitle%
  v_ActivePathOld := v_ActivePath
  v_LeftPathOld := v_LeftPath
  v_RightPathOld := v_RightPath
}
Return

In TC8 erscheint leider nur noch der Separator ohne die Pfade.
1. Was muss ändern, damit das wieder funktioniert?
2. Hat TC8 vielleicht vor das Konfigurieren des Fenstertitels intern zu unterstützen?

icfu · Post by *icfu » 2011-12-04, 10:52 UTC

In TC8 erscheint leider nur noch der Separator ohne die Pfade.
1. Was muss ändern, damit das wieder funktioniert?

Kann ich nicht nachvollziehen, das Skript funktioniert hier problemlos mit der aktuellsten Beta 11.

tom*de · Post by *tom*de » 2011-12-05, 17:09 UTC

Während beim 7.54a kurz nach dem Start die Titelzeile geändert wird, dauert es beim 8.0b11x64 eine Weile(?) bzw. ein paar Aktionen(?) und dann erscheint nur der Separator...
Vielleicht ein Problem beim Einsatz von TPathPanel1,2,3 und der RegExReplace? Habs aber noch nicht gefunden...

icfu · Post by *icfu » 2011-12-05, 17:45 UTC

x64? Dazu kann ich nichts sagen, dieser Kelch ging bisher spurlos an mir vorüber und wird es auch in der näheren Zukunft.
Im x64-TC heißen die Controls evtl. anders, kannst Du selbst rausfinden mit dem AHK/AutoIt-Window Spy durch Überfahren mit der Maus...

x86 funktioniert hier, auch mit AutoHotkey_L, ANSI oder Unicode egal.

tom*de · Post by *tom*de » 2011-12-05, 19:46 UTC

Danke für den Tipp... und dank Ahk Window Spy:

TPathPanel1 heißt in x64 Window9
TPathPanel2 heißt in x64 Window14
TMyPanel3 heißt in x64 Window5

Habs mal im Code eingetragen und es funktioniert für x64/x32 bit, wenn die entsprechenden Kommentare entfernt werden:

Code: Select all

; x32:  ControlGetText, v_ActivePath, TMyPanel3
; x64:  ControlGetText, v_ActivePath, Window5
  v_ActivePath := RegExReplace(v_ActivePath, "(.+)>", "$1\")
; x32:  ControlGetText v_LeftPath, TPathPanel1
; x64:  ControlGetText v_LeftPath, Window9
  v_LeftPath := RegExReplace(v_LeftPath, "(.+\\).*", "$1")
; x32:  ControlGetText v_RightPath, TPathPanel2
; x64:  ControlGetText v_RightPath, Window14

Wär schön, wenn es für beide TC-Versionen läuft - vielleicht incl. einer x64/x32-Unterscheidung im Separator?

Kann jemand helfen?

icfu · Post by *icfu » 2011-12-05, 21:14 UTC

Der "Window Spy" ist bereits im AHK-Paket dabei, aber ein alternativer Spy schadet natürlich nicht...

Angepaßte Skriptversion für x32/x64, unterschiedliche Separatoren konfigurierbar:

Code: Select all

;*** Konfiguration Start
v_Separator32 := "  < | x32 | >  "
v_Separator64 := "  < | x64 | >  "
v_Timer := 250
;*** Konfiguration Ende

#Persistent
SetTimer, Timer, %v_Timer%

Timer:
hWnd := WinActive("ahk_class TTOTAL_CMD")
If (hWnd)
{
  WinGet, v_TCExe, ProcessName, ahk_id %hWnd%
  If (v_TCExe = "totalcmd.exe")
  {
    v_ActivePathControl := "TMyPanel3"
    v_LeftPathControl := "TPathPanel1"
    v_RightPathControl := "TPathPanel2"
    v_Separator := v_Separator32
  }
  Else
  {
    v_ActivePathControl := "Window5"
    v_LeftPathControl := "Window9"
    v_RightPathControl := "Window14"
    v_Separator := v_Separator64
  }
  ControlGetText, v_ActivePath, %v_ActivePathControl%
  v_ActivePath := RegExReplace(v_ActivePath, "(.+)>", "$1\")
  ControlGetText v_LeftPath, %v_LeftPathControl%
  v_LeftPath := RegExReplace(v_LeftPath, "(.+\\).*", "$1")
  ControlGetText v_RightPath, %v_RightPathControl%
  v_RightPath := RegExReplace(v_RightPath, "(.+\\).*", "$1")
  If (v_ActivePath = v_ActivePathOld && v_LeftPath = v_LeftPathOld && v_RightPath = v_RightPathOld)
    Return
  v_InactivePath := (v_ActivePath = v_LeftPath) ? v_RightPath : v_LeftPath
  v_WinTitle := v_ActivePath . v_Separator . v_InactivePath
  WinSetTitle, %v_WinTitle%
  v_ActivePathOld := v_ActivePath
  v_LeftPathOld := v_LeftPath
  v_RightPathOld := v_RightPath
}
Return

tom*de · Post by *tom*de » 2011-12-06, 11:44 UTC

Prima icfu, das funktioniert mit v7, v8 32 und 64bit. Danke Tom.

Horst.Epp · Post by *Horst.Epp » 2011-12-06, 13:24 UTC

The path inserted has stripped the last dir.
c:\tools\autohotkey\scripts
is displayed as
c:\tools\autohotkey

Tested with TC8b11 x64
AHK compiled with AutoHotkey110504

icke1954 · Post by *icke1954 » 2011-12-06, 19:11 UTC

@icfu da ich mich erst seit kurzer Zeit mit dem Thema AHK beschäftige entschuldige die Fragen:
Warum sind die Bezeichnungen der Panels anscheinend immer unterschiedlich, oder ist das bei mir nur so? Dann müßte der Code ja immer, je nach Konfiguration, geändert werden?

Dein Code auf Seite 1 funktionierte bei mir nie:
TMyPanel1 = [LfwName] [Byte] von [Byte] frei (mal rechts, mal links)
TMyPanel2 = [LfwName] [Byte] von [Byte] frei (mal rechts, mal links)
TMyPanel3 =[LfwName] [Byte] von [Byte] frei (mal rechts, mal links)
TMyPanel9 = nie vorhanden
TMyPanel5 = ist fast immer [akt. Pfad] bei Laufwerksliste herunterklappbar = ON ist der Akt.Pfad aber TMyOPanel3

Erst der Code auf Seite2, war mit einer kleinen Änderung, bei mir anwendbar:
Vorraussetzung wie gesagt : Laufwerksliste herunterklappbar = OFF
so ist in TMyPanel5 = Akt.Pfad sonst TMyPanel3
TPathPanel1= Pfad (links oder recht, aber das ist ja egal
TPathPanel2 = Pfad(rechts oder links, aber das ja egal)

Aber verzeih mir die Frage, außer daß es faszinierend programmiert ist und für Leute, die keine Lizenz haben, oder ihren eigenen Namen nicht mehr sehen können, sehe ich keinen tieferen Sinn in dem Tool. Immerhin läuft resistent ein Programm ständig mit, dafür spart man vielleicht 3 mm vertikal an Platz, wenn man den aktuellen Pfad ausblendet.
Bestimmt habe ich was übersehen, hoffe ich doch ...

MfG icke

icfu · Post by *icfu » 2011-12-07, 01:17 UTC

Warum sind die Bezeichnungen der Panels anscheinend immer unterschiedlich, oder ist das bei mir nur so?

Der Klassenname der relevanten Controls hat sich lediglich nach dem letzten Major-Upgrade des TC auf Version 7.50 geändert, wie Du dem Thread entnehmen kannst.
Die Instanzen werden von AHK numeriert und können sich daher ändern, wenn Controls ein- oder ausgeblendet werden, das ist korrekt.

Aus diesem Grund ist es beim AHK-Skripten des TCs wichtig, daß man sich möglichst auf Elemente stützt, deren Instanznummern sich nicht oder nur in seltenen Situationen ändern, ansonsten darf man sich auf viele graue Haare beim programmiertechnischen Abdecken aller Eventualitäten freuen.

Dein Code auf Seite 1 funktionierte bei mir nie:

Du hast wohl nicht mit TC <7.50 getestet.

Erst der Code auf Seite2, war mit einer kleinen Änderung, bei mir anwendbar:
Vorraussetzung wie gesagt : Laufwerksliste herunterklappbar = OFF
so ist in TMyPanel5 = Akt.Pfad sonst TMyPanel3

Korrekt. Wenn Du eine bessere, eindeutige Möglichkeit findest, um TC den aktiven Pfad zu entlocken als eben jenes Control auszulesen, das meistens 'ne 3, manchmal aber 'ne 5 hat: Nur zu!

Aber verzeih mir die Frage, außer daß es faszinierend programmiert ist und für Leute, die keine Lizenz haben, oder ihren eigenen Namen nicht mehr sehen können, sehe ich keinen tieferen Sinn in dem Tool. Immerhin läuft resistent ein Programm ständig mit, dafür spart man vielleicht 3 mm vertikal an Platz, wenn man den aktuellen Pfad ausblendet.
Bestimmt habe ich was übersehen, hoffe ich doch ...

Wenn Du keinen tieferen Sinn drin siehst, mehrere Instanzen eines Dateimanagers an den Pfadnamen beim Task-Switchen zu unterscheiden und stattdessen lieber erfahren möchtest, wie Du heißt, wie der Dateimanager mit dem blauen Diskettenicon heißt und welche Versions- und Instanznummer der Schweizer, der den Anwender mit diesen unglaublich wertvollen Informationen beglückt, dafür ausgewürfelt hat, gehörst Du evtl. nicht zur Zielgruppe dieses Skripts.

Vielleicht hilft dieser Thread, insbesondere das darin verlinkte Bild, beim Verständnis:
http://www.ghisler.ch/board/viewtopic.php?p=86630

Zum Thema "da läuft ein Programm": Nun, das ist korrekt, aber "das Programm" läuft bei denen, die es einmal kennen- und schätzengelernt haben, eh.
Ob da nun noch ein weiteres Skript alle 250ms oder noch seltener einen CPU-Peak von 0,001% erzeugt, kann in Zeiten, in denen man einen kompletten RAM-Riegel und CPU-Kern benötigt, um eine einzige WWW-Seite in Opera, Firefox oder Chromium darzustellen, kein Argument mehr sein.

Ein Leben ohne AHK ist möglich, aber sinnlos.

norfie² · Post by *norfie² » 2011-12-07, 07:13 UTC

[offtopicrant]...aber was will man von einem Entwickler erwarten, der es in zwei Jahrzehnten nicht auf die Reihe bringt, alle 26 cm_GotoDrive-Kommandos in die TOTALCMD.INC einzupflegen...[/offtopicrant]

1 und 1 zusammenzaehlen sollte man aber schon koennen, wenn man mittlerweile "obsolete" Forderungen durchsetzen will. Von 2004 bis jetzt ist noch nicht einmal ein ganzes Jahrzehnt vergangen.

Total Commander

Zusätzliche Info in der Titelzeile anzeigen ...

Pfade auch im Vista Admin-Mode?

Änderung ab TC 7.50

6040