PowerISO - Parameters Command Line

[CZ.M]

2CZ.M
It seems that Skif_off has solved your problem:
http://ghisler.ch/board/viewtopic.php?p=321772#321772

Of course, but if you have a look at the parameters that I wrote about UltraISO
Where is a mistake ?

Command: UltraISO.exe
Parameters: -imax -l -f %N -out %P%S.iso

[CZ.M]

Try this script

Code: Select all

' Command:    "path2script\PowerISOCreate.vbs" "path2PowerISO\piso.exe"
' Parameters: "%T" "%L"

If WScript.Arguments.Length <> 3 Then
  WScript.Echo "Check startup parameters!"
  WScript.Quit
End If

Dim sIsoName, sCmdLine, Str, Str2

sIsoName = InputBox("Enter name", "ISO name", "image")
If IsEmpty(sIsoName) Then
  WScript.Quit
End If

sCmdLine = """" & WScript.Arguments.Item(0) & """ create -o """ & WScript.Arguments.Item(1) & sIsoName & ".iso"""

Set WshShell = CreateObject("WScript.Shell")
Set FSO = CreateObject("Scripting.FileSystemObject")
Set objRegExp = CreateObject("VBScript.RegExp")
objRegExp.Pattern = "\\$"

Set File = FSO.GetFile(WScript.Arguments.Item(2))
Set TextStream = File.OpenAsTextStream(1)
Str = vbNullString
While Not TextStream.AtEndOfStream
  Str2 = TextStream.ReadLine()
  If Right(Str2, 1) = "" Then
    Str = Str & " -add """ & objRegExp.Replace(Str2, "") & """ ""/" & FSO.GetFileName(Str2) & """"
  Else
    Str = Str & " -add """ & Str2 & """ /"
  End If
Wend
TextStream.Close

WshShell.Run sCmdLine & Str, 1, False

Ok?

P.S. If you want add switches then you can add string before

Code: Select all

WshShell.Run sCmdLine & Str, 1, False

Example: add "-udf on":

Code: Select all

TextStream.Close

Str = Str & "-udf on"
WshShell.Run sCmdLine & Str, 1, False

I have one more question. What do I need to change in this script that the image was saved in the first panel? (Now the picture is created in a target panel.)

[Skif_off]

I have one more question. What do I need to change in this script that the image was saved in the first panel? (Now the picture is created in a target panel.)

In params: replace "%T" on "%P".

And it will work fine in normal or branch view (?), but how it will work with search result? With "%T" and target panel it's not a problem.

[CZ.M]

And it will work fine in normal or branch view (?), but how it will work with search result? With "%T" and target panel it's not a problem.

Everything works as I wanted. Once again, thank you for your help.